[BUG] Overloaded message command strip semicolon characters in lists

[josephgarnier]

Describe the bug
In CMake, the message command delimits the elements of a list with a semicolon character when surrounded by quotes. But CMakeTest, by overriding this command in cmake/cmake_test/overrides.cmake, removes this feature.

However, this file states that overriding should only occur when FATAL_ERROR is used: If the first argument is not FATAL_ERROR, this function will behave exactly as the original message().. This doesn't seem to be the case and when I comment the code in the overload function, the bug disappears.

Environment:

• Operating system: Windows 10
• CMake version: 4.0.1

To Reproduce
Steps to reproduce the behavior:

1. In CMakeLists.txt without tests, copy the code bellow.
2. Execute the CMake build command

Expected behavior

Let's assume the following use case without then with a CMakeTest inclusion:

message("------")
set(input_text "A B C")
message("${input_text}") # would give A B C
set(input_list A B C)
message("${input_list}") # would give A;B;C
set(input_list "A" "B" "C")
message("${input_list}") # would give A;B;C
set(input_list "A" "B" "C")
message(${input_list}) # would give ABC

include(cmake_test/cmake_test OPTIONAL RESULT_VARIABLE cmake_test_found)

message("------")
set(input_text "A B C")
message("${input_text}") # would give A B C => OK
set(input_list A B C)
message("${input_list}") # would give A;B;C => not OK, give ABC
set(input_list "A" "B" "C")
message("${input_list}") # would give A;B;C => not OK, give ABC
set(input_list "A" "B" "C")
message(${input_list}) # would give ABC => OK

[josephgarnier]

Here's a suggested fix for cmake/cmake_test/overrides.cmake, which seems covers all possible uses of the message command.

Replace:

if("${ARGV}" STREQUAL "")
    _message("")
else()
    _message(${ARGV})
endif()

By:

    if (${ARGC} EQUAL 0)
         _message("")
    elseif (${ARGC} EQUAL 1)
        _message("${ARGV0}")
    else()
        set(valid_message_modes
            "FATAL_ERROR"
            "SEND_ERROR"
            "WARNING"
            "AUTHOR_WARNING"
            "DEPRECATION"
            "NOTICE"
            "STATUS"
            "VERBOSE"
            "DEBUG"
            "TRACE"
            "CHECK_START"
            "CHECK_PASS"
            "CHECK_FAIL"
        )
        set(first_arg "${ARGV0}")
        if ("${first_arg}" IN_LIST valid_message_modes)
            list(REMOVE_AT ARGV 0)
            string(JOIN "" msg ${ARGV})
            _message("${first_arg}" "${msg}")
        else()
            string(JOIN "" msg ${ARGV})
            _message("${msg}")
        endif()
    endif()

The list of modes in valid_message_modes comes from cmMessageCommand.cxx L86 and from the doc of message().

[ryanmrichard]

Thanks for posting this! I'm not ignoring these. I'm hoping to get to these issues early next week. I've been absolutely swamped the last couple of weeks (here at Iowa State University, we just started our undergrad summer internships, and that's been taking up all of my time).

[ryanmrichard]

@zachcran are you actively working on this? If not, I can look at it.

[zachcran]

@ryanmrichard Yes, although I don't have a lot of time per week to dedicate to it. I was hoping to get to it at the end of this week. So far I have implemented the suggested fix on my test machine and verified that it resolves the issue, but I haven't created the test for this behavior. AFAIK the message override does not have any tests yet, so step #1 is creating tests/cmake_test/overrides.cmake.

[josephgarnier]

If I may, to avoid spending too much time on tests, you can take inspiration from the official tests, available here for message() command. To test the display of a list, you should instead look at LIST-nonexistent.cmake.

You have one CMake file per use case. The test functions are in CMake files, while the expected results are in the <name>-result.txt or <name>-result.stdout files.

[zachcran]

@josephgarnier Thanks for the tip! That should make getting the right tests up and running much easier.

[josephgarnier]

Edit : Here is a fix... of my fix (although I think it can be optimized to reduce repetition).

    if (${ARGC} EQUAL 0)
         _message("")
    elseif (${ARGC} EQUAL 1)
        _message("${ARGV0}")
    else()
        set(valid_message_modes
            "FATAL_ERROR"
            "SEND_ERROR"
            "WARNING"
            "AUTHOR_WARNING"
            "DEPRECATION"
            "NOTICE"
            "STATUS"
            "VERBOSE"
            "DEBUG"
            "TRACE"
            "CHECK_START"
            "CHECK_PASS"
            "CHECK_FAIL"
        )
        set(first_arg "${ARGV0}")
        if ("${first_arg}" IN_LIST valid_message_modes)
            list(REMOVE_AT ARGV 0)
            if(${ARGC} EQUAL 2)
                 _message("${first_arg}" "${ARGV}")
            else()
                 string(JOIN "" msg ${ARGV})
                _message("${first_arg}" "${msg}")
            endif()
        else()
            _message(${ARGV})
        endif()
    endif()

I think I've now covered all use cases:

message("")
message("a")
message("a b")
message("a;b")
message("a" "b")
message(STATUS "")
message(STATUS "a")
message(STATUS "a b")
message(STATUS "a;b")
message(STATUS "a" "b")

Output:

# Result without CMakeTest
[cmake] 
[cmake] a
[cmake] a b
[cmake] a;b
[cmake] ab
[cmake] -- 
[cmake] -- a
[cmake] -- a b
[cmake] -- a;b
[cmake] -- ab

# Result with CMakeTest
[cmake] 
[cmake] a
[cmake] a b
[cmake] a;b
[cmake] ab
[cmake] -- 
[cmake] -- a
[cmake] -- a b
[cmake] -- a;b
[cmake] -- ab