Split keyword captures into subgroups (#108)

This introduces the backwards compatible captures:
- `@keyword.definition`
- `@keyword.import`
- `@keyword.control.conditional`
- `@keyword.control.repeat`
- `@keyword.exception`
- `@keyword.operator`
- `@keyword.operator.regex` (used by the `~r` sigil modifiers)

Additionally, this also defines the `@label.modifier` capture for all
other sigil modifiers

Author: AlternateRT

.tsqueryrc.json

@@ -38,9 +38,17 @@
       "function.special.call": "Captures built-in function calls",
       "hint": "Captures hints",
       "keyword": "Captures keywords",
-      "keyword.exception": "Captures keywords for exception handling",
+      "keyword.control": "Captures control flow keywords",
+      "keyword.control.conditional": "Captures conditional control flow keywords",
+      "keyword.control.repeat": "Captures loop control flow keywords",
+      "keyword.control.return": "Captures return control flow keywords",
+      "keyword.definition": "Captures definition keywords",
+      "keyword.exception": "Captures exception handling keywords",
       "keyword.import": "Captures import keywords",
+      "keyword.operator": "Captures operator keywords",
+      "keyword.operator.regex": "Captures regex mode modifiers",
       "label": "Captures labels",
+      "label.modifier": "Captures modifiers",
       "link_text": "Captures link text",
       "link_uri": "Captures link URIs",
       "number": "Captures numeric values",

languages/elixir/highlights.scm

@@ -102,6 +102,9 @@
   quoted_start: _ @string.special
   quoted_end: _ @string.special) @string.special
 
+; Sigil modifiers
+(sigil_modifiers) @label.modifier
+
 ; String/charlist sigils
 (sigil
   (sigil_name) @_sigil_name @string
@@ -114,6 +117,7 @@
   (sigil_name) @_sigil_name @string.regex
   quoted_start: _ @string.regex
   quoted_end: _ @string.regex
+  (sigil_modifiers)? @keyword.operator.regex
   (#any-of? @_sigil_name "R" "r")) @string.regex
 
 ; Phoenix HEEx template sigil
@@ -239,7 +243,7 @@
 
 ; Function/macro definitions
 (call
-  target: (identifier) @keyword
+  target: (identifier) @keyword.definition
   (arguments
     [
       (identifier) @function
@@ -257,7 +261,7 @@
         operator: "|>"
         right: (identifier) @variable)
     ])
-  (#any-of? @keyword
+  (#any-of? @keyword.definition
     "def" "defp" "defdelegate" "defguard" "defguardp" "defmacro" "defmacrop" "defn" "defnp"
     "deftransform" "deftransformp"))
 
@@ -343,32 +347,64 @@
 
 ; Definition keywords
 (call
-  target: (identifier) @keyword
-  (#any-of? @keyword
+  target: (identifier) @keyword.definition
+  (#any-of? @keyword.definition
     "def" "defp" "defdelegate" "defoverridable" "defguard" "defguardp" "defmacro" "defmacrop"
     "defstruct" "defexception" "defrecord" "defrecordp" "defmodule" "defprotocol" "defimpl" "defn"
     "defnp" "deftransform" "deftransformp"))
 
-; Kernel/special form keywords
+; Reserved definition keyword
+"fn" @keyword.definition
+
+; Module import keywords
+(call
+  target: (identifier) @keyword.import
+  (#any-of? @keyword.import "alias" "import" "require" "use"))
+
+; Control flow keywords
+(call
+  target: (identifier) @keyword.control.conditional
+  (#any-of? @keyword.control.conditional "case" "cond" "if" "receive" "unless" "with"))
+
+; Reserved control flow keywords
+[
+  "after"
+  "else"
+] @keyword.control.conditional
+
+; List comprehension keyword
+(call
+  target: (identifier) @keyword.control.repeat
+  (#eq? @keyword.control.repeat "for"))
+
+; Exception handling keywords
+(call
+  target: (identifier) @keyword.exception
+  (#any-of? @keyword.exception "raise" "reraise" "throw" "try"))
+
+; Reserved exception handling keywords
+[
+  "catch"
+  "rescue"
+] @keyword.exception
+
+; Metaprogramming keywords
 (call
   target: (identifier) @keyword
-  (#any-of? @keyword
-    "alias" "case" "cond" "else" "for" "if" "import" "quote" "raise" "receive" "require" "reraise"
-    "super" "throw" "try" "unless" "unquote" "unquote_splicing" "use" "with"))
+  (#any-of? @keyword "quote" "super" "unquote" "unquote_splicing"))
 
-; Reserved keywords
+; Operator keywords
 [
-  "when"
   "and"
-  "or"
-  "not"
   "in"
+  "not"
   "not in"
-  "fn"
+  "or"
+  "when"
+] @keyword.operator
+
+; Do-end block keywords
+[
   "do"
   "end"
-  "catch"
-  "rescue"
-  "after"
-  "else"
 ] @keyword