Add support for EEx templates (#101)

Reuse `tree-sitter-heex` to support the more generic `EEx` templates

Author: AlternateRT

.tsqueryrc.json

@@ -5,6 +5,9 @@
     "languages/([^/]+)/[^/]+\\.scm",
     "grammars/([^/]+)/queries/[^/]+\\.scm"
   ],
+  "parser_aliases": {
+    "eex": "heex"
+  },
   "valid_captures": {
     "brackets": {
       "open": "Captures opening brackets, braces, and quotes",

extension.toml

@@ -13,44 +13,52 @@ repository = "https://github.com/zed-extensions/elixir"
 name = "Expert"
 languages = [
     "Elixir",
+    "EEx",
     "HEEx",
 ]
 
 [language_servers.expert.language_ids]
 "Elixir" = "elixir"
+"EEx" = "eex"
 "HEEx" = "heex"
 
 [language_servers.elixir-ls]
 name = "ElixirLS"
 languages = [
     "Elixir",
+    "EEx",
     "HEEx",
 ]
 
 [language_servers.elixir-ls.language_ids]
 "Elixir" = "elixir"
+"EEx" = "eex"
 "HEEx" = "heex"
 
 [language_servers.next-ls]
 name = "Next LS"
 languages = [
     "Elixir",
+    "EEx",
     "HEEx",
 ]
 
 [language_servers.next-ls.language_ids]
 "Elixir" = "elixir"
+"EEx" = "eex"
 "HEEx" = "heex"
 
 [language_servers.lexical]
 name = "Lexical"
 languages = [
     "Elixir",
+    "EEx",
     "HEEx",
 ]
 
 [language_servers.lexical.language_ids]
 "Elixir" = "elixir"
+"EEx" = "eex"
 "HEEx" = "heex"
 
 [grammars.elixir]

languages/eex/brackets.scm

@@ -0,0 +1,4 @@
+(directive
+  _ @open
+  (_)
+  "%>" @close)

languages/eex/config.toml

@@ -0,0 +1,16 @@
+name = "EEx"
+grammar = "heex"
+path_suffixes = ["eex"]
+block_comment = { start = "<%!-- ", prefix = "", end = " --%>", tab_size = 0 }
+autoclose_before = ";:.,=}])>%"
+brackets = [
+    { start = "{", end = "}", close = true, newline = true },
+    { start = "[", end = "]", close = true, newline = true },
+    { start = "(", end = ")", close = true, newline = true },
+    { start = "<", end = ">", close = true, newline = true },
+    { start = "%", end = "%", close = true, newline = true },
+    { start = "\"", end = "\"", close = true, newline = false, not_in = ["comment"] },
+    { start = "'", end = "'", close = true, newline = false, not_in = ["comment"] },
+    { start = "!--", end = " --", close = true, newline = false, not_in = ["comment"] },
+]
+tab_size = 2

languages/eex/highlights.scm

@@ -0,0 +1,18 @@
+; Directive expressions can use the following tag delimiters:
+;     `<%` and `%>`
+;     `<%=` and `%>`
+;     `<%%` and `%>`
+;     `<%%=` and `%>`
+(directive) @keyword
+
+; Comments can use the following tag delimiters:
+;     `<%!--` and `--%>`
+;     `<%#` and `%>`
+[
+  (comment
+    "<%!--"
+    "--%>")
+  (comment
+    "<%#"
+    "%>")
+] @comment

languages/eex/injections.scm

@@ -0,0 +1,32 @@
+; Directives are standalone tags like `<%= @x %>`
+;
+; Directives with `partial_expression_value` or `ending_expression_value`
+; nodes are Elixir code that is part of an expression that spans multiple
+; `directive` nodes, so they must be combined. For example:
+;     <%= if true do %>
+;       Hello, tree-sitter!
+;     <% end %>
+(directive
+  [
+    (partial_expression_value)
+    (ending_expression_value)
+  ] @injection.content
+  (#set! injection.language "elixir")
+  (#set! injection.combined))
+
+; Directives with `expression_value` nodes do not need to be combined.
+; For example: `<%= @content %>`
+(directive
+  (expression_value) @injection.content
+  (#set! injection.language "elixir"))
+
+; Comment parsing languages support
+((comment
+  "<%!--"
+  "--%>") @injection.content
+  (#set! injection.language "comment"))
+
+((comment
+  "<%#"
+  "%>") @injection.content
+  (#set! injection.language "comment"))

languages/eex/outline.scm

@@ -0,0 +1,8 @@
+[
+  (comment
+    "<%!--"
+    "--%>")
+  (comment
+    "<%#"
+    "%>")
+] @annotation

languages/eex/overrides.scm

@@ -0,0 +1,8 @@
+[
+  (comment
+    "<%!--"
+    "--%>")
+  (comment
+    "<%#"
+    "%>")
+] @comment

languages/heex/injections.scm

@@ -4,9 +4,9 @@
   (expression_value) @injection.content
   (#set! injection.language "elixir"))
 
-; Directives are standalone tags like '<%= @x %>'
+; Directives are standalone tags like `<%= @x %>`
 ;
-; Directives with `partial_expression_value` and `ending_expression_value`
+; Directives with `partial_expression_value` or `ending_expression_value`
 ; nodes are Elixir code that is part of an expression that spans multiple
 ; `directive` nodes, so they must be combined. For example:
 ;     <%= if true do %>