This makes PhASAR a package that can be used via find_package() in an out-of-tree tool. Dependent libraries, include dirs and definitions are propagated to the out-of-tree tool. See https://github.com/MMory/OOTPhasarToolDemo for an example.

Author: MMory

CMakeLists.txt

@@ -101,7 +101,6 @@ endif()
 # Boost
 find_package(Boost 1.65.1 COMPONENTS filesystem graph system program_options log ${BOOST_THREAD} REQUIRED)
 include_directories(${Boost_INCLUDE_DIRS})
-add_definitions(-DBOOST_LOG_DYN_LINK)
 
 # JSON library
 option(JSON_BuildTests OFF)
@@ -231,6 +230,8 @@ if (PHASAR_BUILD_IR)
   add_subdirectory(test)
 endif()
 
+set(INCLUDE_INSTALL_DIR include/ CACHE PATH "Install dir of headers")
+
 # Install targets of phasar-llvm, other executables, and libraries are to be
 # found in the individual subdirectories of tools/
 
@@ -271,6 +272,33 @@ install(DIRECTORY config/
               WORLD_READ
 )
 
+install(EXPORT phasarTargets
+  DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/phasar
+  NAMESPACE phasar::
+  FILE phasarTargets.cmake
+)
+
+include(CMakePackageConfigHelpers)
+configure_package_config_file(
+  Config.cmake.in
+  phasarConfig.cmake
+  INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/phasar
+  PATH_VARS INCLUDE_INSTALL_DIR
+  )
+
+write_basic_package_version_file(
+  ${CMAKE_CURRENT_BINARY_DIR}/phasarConfigVersion.cmake
+  VERSION 1.0.0
+  COMPATIBILITY SameMajorVersion
+  )
+
+### Install Config and ConfigVersion files
+install(
+  FILES "${CMAKE_CURRENT_BINARY_DIR}/phasarConfig.cmake"
+        "${CMAKE_CURRENT_BINARY_DIR}/phasarConfigVersion.cmake"
+  DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/phasar"
+  )
+
 # If the Phasar shared object libraries are not installed into a system folder
 # the so libs must be added manually to the linker search path and the linker
 # config must be updated as follows:

Config.cmake.in

@@ -0,0 +1,7 @@
+set(PHASAR_VERSION 1.0.0)
+
+@PACKAGE_INIT@
+set_and_check(PHASAR_INCLUDE_DIR "@PACKAGE_INCLUDE_INSTALL_DIR@")
+include( "${CMAKE_CURRENT_LIST_DIR}/phasarTargets.cmake" )
+
+check_required_components(phasar)

cmake/phasar_macros.cmake

@@ -160,6 +160,7 @@ macro(add_phasar_library name)
     set(libkind)
   endif()
   add_library( ${name} ${libkind} ${srcs} )
+  add_library( phasar::${name} ALIAS ${name} )
   if( LLVM_COMMON_DEPENDS )
     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
   endif( LLVM_COMMON_DEPENDS )
@@ -188,6 +189,7 @@ macro(add_phasar_library name)
   endif(MSVC)
   install(TARGETS ${name}
     EXPORT LLVMExports
+    EXPORT phasarTargets
     LIBRARY DESTINATION lib
     ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
   set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})

lib/PhasarClang/CMakeLists.txt

@@ -22,6 +22,7 @@ endif()
 find_package(Boost COMPONENTS log REQUIRED)
 target_link_libraries(phasar_clang
   LINK_PUBLIC
+  phasar_utils
   clangTooling
   clangFrontendTool
   clangFrontend

lib/Utils/CMakeLists.txt

@@ -16,7 +16,6 @@ set(LLVM_LINK_COMPONENTS
   BitWriter
 )
 
-
 if(BUILD_SHARED_LIBS)
   add_phasar_library(phasar_utils
     SHARED
@@ -29,11 +28,40 @@ else()
   )
 endif()
 
+set(LLVM_LINK_COMPONENTS
+  coverage
+  coroutines
+  libdriver
+  lto
+  support
+  analysis
+  bitwriter
+  core
+  ipo
+  irreader
+  instcombine
+  instrumentation
+  linker
+  objcarcopts
+  scalaropts
+  transformutils
+  codegen
+  vectorize
+)
+
+llvm_map_components_to_libnames(llvm_libs
+  ${LLVM_LINK_COMPONENTS}
+)
+
+target_include_directories(phasar_utils PUBLIC ${LLVM_INCLUDE_DIRS})
+target_compile_definitions(phasar_utils PUBLIC -DBOOST_LOG_DYN_LINK)
+
 find_package(Boost COMPONENTS log REQUIRED)
 target_link_libraries(phasar_utils
   LINK_PUBLIC
   ${Boost_LIBRARIES}
   ${CMAKE_DL_LIBS}
+  ${llvm_libs}
 )
 
 set_target_properties(phasar_utils