mparticle-android-sdk/build.gradle at 5f64a51a09bff26b718f54572c914900c7da6044 · mParticle/mparticle-android-sdk · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
buildscript {
    ext.kotlin_version = '1.9.0'
    ext.gradle_version = '7.3.1'

    repositories {
        mavenCentral()
        google()
    }
    dependencies {
        classpath "com.android.tools.build:gradle:$gradle_version"
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

plugins {
    id "org.sonarqube" version "3.5.0.2730"
    id "org.jlleitschuh.gradle.ktlint" version "14.0.1"
}

sonarqube {
    properties {
        property "sonar.projectKey", "mParticle_mparticle-android-sdk"
        property "sonar.organization", "mparticle"
        property "sonar.host.url", "https://sonarcloud.io"
    }
}

subprojects {
    apply plugin: 'org.sonarqube'
    sonarqube {
        androidVariant "release"
    }
    apply plugin: 'org.jlleitschuh.gradle.ktlint'
}

allprojects {
    group = 'com.mparticle'
    version = '5.75.1-SNAPSHOT'
    if (project.hasProperty('isRelease') && project.isRelease) {
        version = version.toString().replace("-SNAPSHOT", "")
    }

    repositories {
        mavenLocal()
        google()
        mavenCentral()
    }

    tasks.withType(Javadoc) {
        options.addStringOption('Xdoclint:none', '-quiet')
    }

    apply plugin: 'org.jlleitschuh.gradle.ktlint'

    // Apply shared signing configuration to all Android projects
    afterEvaluate { project ->
        if (project.hasProperty('android')) {
            android {
                signingConfigs {
                    debug {
                        storeFile file("${rootProject.projectDir}/debug.keystore")
                        storePassword "android"
                        keyAlias "androiddebugkey"
                        keyPassword "android"
                    }
                }
                buildTypes {
                    debug {
                        signingConfig signingConfigs.debug
                    }
                }
            }
        }
    }
}