smb/client: autogenerate SMB1 NT status to DOS error mapping

Introduce `gen_smb1_mapping` script to autogenerate the NT status to
DOS error mapping table for SMB1. This script parses nterr.h to
generate smb1_mapping_table.c, which is then directly included as
the content of the ntstatus_to_dos_map[] array at compile time.

The generated array is numerically sorted during the build process to
ensure a consistent structure, providing the necessary groundwork for
future introduction of binary search lookups.

Signed-off-by: Huiwen He <hehuiwen@kylinos.cn>
Reviewed-by: ChenXiaoSong <chenxiaosong@kylinos.cn>
Signed-off-by: Steve French <stfrench@microsoft.com>

Author: haryven

fs/smb/client/.gitignore

@@ -1 +1,2 @@
+smb1_mapping_table.c
 smb2_mapping_table.c

fs/smb/client/Makefile

@@ -44,6 +44,21 @@ cifs-$(CONFIG_CIFS_ALLOW_INSECURE_LEGACY) += \
 
 cifs-$(CONFIG_CIFS_COMPRESSION) += compress.o compress/lz77.o
 
+ifneq ($(CONFIG_CIFS_ALLOW_INSECURE_LEGACY),)
+#
+# Build the SMB1 error mapping tables from nterr.h
+#
+smb1-gen-y := smb1_mapping_table.c
+
+$(obj)/smb1_mapping_table.c: $(src)/nterr.h $(src)/gen_smb1_mapping FORCE
+	$(call if_changed,gen_smb1_mapping)
+
+$(obj)/smb1maperror.o: $(addprefix $(obj)/, $(smb1-gen-y))
+
+quiet_cmd_gen_smb1_mapping = GEN     $@
+      cmd_gen_smb1_mapping = perl $(src)/gen_smb1_mapping $< $@
+endif
+
 #
 # Build the SMB2 error mapping table from smb2status.h
 #
@@ -59,4 +74,4 @@ quiet_cmd_gen_smb2_mapping = GEN     $@
 obj-$(CONFIG_SMB_KUNIT_TESTS) += smb2maperror_test.o
 
 # Let Kbuild handle tracking and cleaning
-targets += smb2_mapping_table.c
+targets += smb2_mapping_table.c $(smb1-gen-y)

fs/smb/client/gen_smb1_mapping

@@ -0,0 +1,91 @@
+#!/usr/bin/perl -w
+# SPDX-License-Identifier: GPL-2.0-or-later
+#
+# Script to generate SMB1 error mapping tables.
+#
+# Copyright (C) 2026 KylinSoft Co., Ltd. All rights reserved.
+# Author(s): Huiwen He <hehuiwen@kylinos.cn>
+#            ChenXiaoSong <chenxiaosong@kylinos.cn>
+#
+use strict;
+
+if ($#ARGV != 1) {
+	print STDERR "Usage: $0 <in-file> <out-file>\n";
+	exit(2);
+}
+
+# Parse input parameters and extract filenames
+my $in_file  = $ARGV[0];
+my $out_file = $ARGV[1];
+my $input_name  = (split m|/|, $in_file)[-1];
+my $output_name = (split m|/|, $out_file)[-1];
+my $script_name = (split m|/|, $0)[-1];
+my @list     = ();
+my %seen     = ();
+
+# Parse annotated entries from the input file
+open(my $in, "<", $in_file) or die "Cannot open $in_file: $!";
+if ($in_file =~ /nterr\.h$/) {
+	while (<$in>) {
+		# Handle backslash line continuation
+		$_ .= <$in> while s/\\\s*\n//;
+
+		# Match #define NT_STATUS_... followed by // CLASS, CODE or /* CLASS, CODE */
+		my $re = qr{^\s*#define\s+(NT_STATUS_[A-Za-z0-9_]+)\s+(.+?)\s*} .
+			 qr{(?://\s*|/\*\s*)([A-Z0-9_]+)\s*,\s*([A-Za-z0-9_]+)};
+
+		if (/$re/) {
+			my ($name, $val_str, $class, $code) = ($1, $2, $3, $4);
+
+			# Skip duplicate macro names
+			next if $seen{$name}++;
+
+			# Clean up value string (remove parens, spaces)
+			$val_str =~ s/[\s\(\)]//g;
+			my $val = 0;
+			foreach my $part (split(/\|/, $val_str)) {
+				$val |= hex($part);
+			}
+			push @list, { val => $val, name => $name, class => $class, code => $code };
+		} elsif (/^\s*#define\s+NT_STATUS_.*(?:\/\/|\/\*)/) {
+			# Error if macro has a comment (// or /*) but fails mapping format
+			die "Error: Invalid mapping comment format in $in_file: $_";
+		}
+	}
+}
+close($in);
+
+# Fail if no entries were found to avoid broken builds
+die "Error: No mapping entries found in $in_file\n" unless @list;
+
+# Sort entries numerically by value
+@list = sort { $a->{val} <=> $b->{val} } @list;
+
+# Generate the C mapping table output file
+open(my $out, ">", $out_file) or die "Cannot open $out_file: $!";
+print $out "/* Autogenerated from $input_name by $script_name */\n\n";
+
+if ($output_name eq "smb1_mapping_table.c") {
+	# Generate NT status -> DOS error mapping file
+
+	my $count = scalar @list;
+	my $full_names = "";
+
+	for (my $i = 0; $i < $count; $i++) {
+		my $e = $list[$i];
+		my $val = $e->{val};
+
+		$full_names .= $e->{name};
+
+		# Merge synonyms
+		if ($i < $count - 1 && $list[$i + 1]->{val} == $val) {
+			$full_names .= " or ";
+			next;
+		}
+
+		printf $out "\t{ %s, %s, 0x%08x, \"%s\" },\n", $e->{class}, $e->{code}, $val, $full_names;
+
+		$full_names = "";
+	}
+}
+close($out);

fs/smb/client/nterr.h

@@ -30,6 +30,10 @@ extern const struct nt_err_code_struct nt_errs[];
 /*
  * NTSTATUS Values extracted using a loop in smbclient then printing a netmon
  * sniff to a file.
+ *
+ * The comment at the end of each definition indicates `dos_class`
+ * and `dos_code` fields of the `ntstatus_to_dos_map` array; it is
+ * used to generate the `smb1_mapping_table.c` file.
  */
 
 #define NT_STATUS_OK                   0x0000	// SUCCESS, 0