Add static Layer methods to create a Layer from a Geometry or a List of Geometries.

Author: jericks

src/main/groovy/geoscript/layer/Layer.groovy

@@ -1964,4 +1964,50 @@ class Layer implements Renderable {
 
         outLayer
     }
+
+    /**
+     * Create a Layer from a Geometry
+     * @param options Optional named parameters:
+     * <ul>
+     *     <li>proj = The Projection (defaults to EPSg:4326)</li>
+     *     <li>style = A Symbolizer</li>
+     * </ul>
+     * @param name The name of the new Layer
+     * @param geometry The Geometry
+     * @return The Layer
+     */
+    static Layer fromGeometry(Map options = [:], String name, Geometry geometry) {
+        String geometryType = geometry.geometryType
+        String epsg = options.get("proj", new Projection("EPSG:4326")).epsg
+        Symbolizer symbolizer = options.get("style", Symbolizer.getDefault(geometryType))
+        Layer layer = new Layer(name, new Schema(name, "geom:${geometryType}:srid=${epsg}"))
+        layer.add([geom: geometry])
+        layer.style = symbolizer
+        layer
+    }
+
+    /**
+     * Create a Layer from a List of Geometries
+     * @param options Optional named parameters:
+     * <ul>
+     *     <li>proj = The Projection (defaults to EPSg:4326)</li>
+     *     <li>style = A Symbolizer</li>
+     * </ul>
+     * @param name The name of the new Layer
+     * @param geometries The List of Geometries
+     * @return The Layer
+     */
+    static Layer fromGeometries(Map options = [:], String name, List<Geometry> geometries) {
+        List<String> geometryTypes = geometries.collect{ Geometry geometry -> geometry.geometryType}.unique()
+        String geometryType = geometryTypes.size() > 1 ? "GeometryCollection" : geometryTypes[0]
+        String epsg = options.get("proj", new Projection("EPSG:4326")).epsg
+        Symbolizer symbolizer = options.get("style", Symbolizer.getDefault(geometryType))
+        Layer layer = new Layer(name, new Schema(name, "geom:${geometryType}:srid=${epsg}"))
+        geometries.each { Geometry geometry ->
+            layer.add([geom: geometry])
+        }
+        layer.style = symbolizer
+        layer
+    }
+
 }

src/test/groovy/geoscript/layer/LayerTestCase.groovy

@@ -2,6 +2,7 @@ package geoscript.layer
 
 import geoscript.AssertUtil
 import geoscript.filter.Expression
+import geoscript.style.Stroke
 import geoscript.workspace.Directory
 import groovy.json.JsonSlurper
 import org.junit.Rule
@@ -39,6 +40,38 @@ class LayerTestCase {
         assertEquals "stations", layer4.name
     }
 
+    @Test void fromGeometry() {
+        Layer layer = Layer.fromGeometry("world", new Bounds(-180,-90,180,90).geometry)
+        assertEquals("world", layer.name)
+        assertEquals(1, layer.count)
+        assertEquals("EPSG:4326", layer.proj.id)
+
+        layer = Layer.fromGeometry("world", new Bounds(-180,-85,180,85, "EPSG:4326").reproject("EPSG:3857").geometry,
+                proj: new Projection("EPSG:3857"),
+                style: new Stroke("black", 0.50)
+        )
+        assertEquals("world", layer.name)
+        assertEquals(1, layer.count)
+        assertEquals("EPSG:3857", layer.proj.id)
+    }
+
+    @Test void fromGeometries() {
+        Layer layer = Layer.fromGeometries("testPits", Geometry.createRandomPoints(new Bounds(-180,-90,180,90).geometry, 10).geometries)
+        assertEquals("testPits", layer.name)
+        assertEquals("Point", layer.schema.geom.typ)
+        assertEquals(10, layer.count)
+        assertEquals("EPSG:4326", layer.proj.id)
+
+        layer = Layer.fromGeometries("geometries", [new Point(1,2), new LineString([1,2],[3,4])],
+            proj: new Projection("EPSG:4326"),
+            style: new Stroke("blue", 1)
+        )
+        assertEquals("geometries", layer.name)
+        assertEquals("GeometryCollection", layer.schema.geom.typ)
+        assertEquals(2, layer.count)
+        assertEquals("EPSG:4326", layer.proj.id)
+    }
+
     @Test void eachFeature() {
         Layer layer = new Shapefile(new File(getClass().getClassLoader().getResource("states.shp").toURI()))
         int count = 0