Read a Map from a json configuration string

jericks · jericks · commit 10a4b0aaa6b5 · 2020-12-15T19:31:06.000-08:00
diff --git a/src/main/groovy/geoscript/render/io/JsonMapReader.groovy b/src/main/groovy/geoscript/render/io/JsonMapReader.groovy
@@ -0,0 +1,55 @@
+package geoscript.render.io
+
+import geoscript.geom.Bounds
+import geoscript.layer.Renderables
+import geoscript.render.Map as GMap
+import groovy.json.JsonSlurper
+
+/**
+ * Read a Map from a JSON String.
+ * <pre>
+ * {
+ *    "width": 400,
+ *    "height": 400,
+ *    "type": "png",
+ *    "backgroundColor": "blue",
+ *    "proj": "EPSG:4326",
+ *    "bounds": {
+ *        "minX": -135.911779,
+ *        "minY": 36.993573,
+ *        "maxX": -96.536779,
+ *        "maxY": 51.405899
+ *    },
+ *    "layers": [
+ *        {"layertype": "layer", "file": "states.shp"}
+ *    ]
+ * }
+ * </pre>
+ * @author Jared Erickson
+ */
+class JsonMapReader implements MapReader {
+
+    @Override
+    GMap read(String str) {
+        JsonSlurper jsonSlurper = new JsonSlurper()
+        Map values = jsonSlurper.parseText(str)
+        GMap map = new GMap(
+            width: values.get("width", 600),
+            height: values.get("height", 400),
+            type: values.get("type", "png"),
+            backgroundColor: values.get("backgroundColor"),
+            fixAspectRatio: values.get("fixAspectRation", true),
+            proj: values.get("proj"),
+            layers: Renderables.getRenderables(values.get("layers"))
+        )
+        if (values.get("proj")) {
+            map.proj = values.get("proj")
+        }
+        if (values.get("bounds")) {
+            Map bounds = values.get("bounds")
+            map.bounds = new Bounds(bounds.minX, bounds.minY, bounds.maxX, bounds.maxY, bounds?.proj)
+        }
+        map
+    }
+
+}
diff --git a/src/main/groovy/geoscript/render/io/MapReader.groovy b/src/main/groovy/geoscript/render/io/MapReader.groovy
@@ -0,0 +1,17 @@
+package geoscript.render.io
+
+import geoscript.render.Map as GMap
+
+/**
+ * Read a Map from a configuration string.
+ * @author Jared Erickson
+ */
+interface MapReader {
+
+    /**
+     * Read a Map from a configuration string.
+     * @param str The string
+     * @return A Map
+     */
+    GMap read(String str)
+}
diff --git a/src/main/groovy/geoscript/render/io/package.html b/src/main/groovy/geoscript/render/io/package.html
@@ -0,0 +1,9 @@
+<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
+<html>
+  <head>
+    <title>package geoscript.render.io.*</title>
+  </head>
+  <body>
+      <p>GeoScript's Render I/O API</p>
+  </body>
+</html>
diff --git a/src/test/groovy/geoscript/render/io/JsonMapReaderTestCase.groovy b/src/test/groovy/geoscript/render/io/JsonMapReaderTestCase.groovy
@@ -0,0 +1,48 @@
+package geoscript.render.io
+
+import geoscript.render.Map
+import org.junit.Test
+import static org.junit.Assert.*
+
+class JsonMapReaderTestCase {
+
+    @Test void readWithOptions() {
+        MapReader mapReader = new JsonMapReader()
+        String dir = new File("src/test/resources").absolutePath
+        Map map = mapReader.read("""{
+            "width": 400,
+            "height": 400,
+            "type": "png",
+            "backgroundColor": "blue",
+            "proj": "EPSG:4326",
+            "bounds": {
+                "minX": -135.911779,
+                "minY": 36.993573,
+                "maxX": -96.536779,
+                "maxY": 51.405899
+            },
+            "layers": [
+                {"layertype": "layer", "file": "${dir}/states.shp"}
+            ]
+        }""")
+        assertEquals(400, map.width)
+        assertEquals(400, map.height)
+        assertEquals("png", map.type)
+        assertEquals("#0000ff", map.backgroundColor)
+        assertEquals(1, map.layers.size())
+    }
+
+    @Test void read() {
+        MapReader mapReader = new JsonMapReader()
+        String dir = new File("src/test/resources").absolutePath
+        Map map = mapReader.read("""{
+            "layers": [
+                {"layertype": "layer", "file": "${dir}/states.shp"}
+            ]
+        }""")
+        assertEquals(600, map.width)
+        assertEquals(400, map.height)
+        assertEquals("png", map.type)
+        assertEquals(1, map.layers.size())
+    }
+}
