libogc2/PKGBUILD at master · extremscorner/libogc2 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
# Maintainer: Extrems <extrems@extremscorner.org>

_pkgname=libogc2
pkgname=(${_pkgname}{,-docs}-git)
pkgver=r2356.90258bd
pkgrel=1
pkgdesc='C library for GameCube and Wii targeting devkitPPC.'
arch=('any')
url='https://github.com/extremscorner/libogc2'
license=('custom')
groups=('gamecube-dev' 'wii-dev')
depends=('devkitPPC>=r49' 'gamecube-tools' 'ppc-libmad')
makedepends=('doxygen' 'git')
options=(!strip libtool staticlibs)

prepare() {
	cd "${startdir}"
	git update-index --assume-unchanged PKGBUILD
}

pkgver() {
	cd "${startdir}"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
}

build() {
	cd "${startdir}"
	make
	make docs
}

package_libogc2-git() {
	optdepends=(${_pkgname}{-docs-git,-examples})
	provides=("${_pkgname}")
	conflicts=("${_pkgname}")

	cd "${startdir}"
	DESTDIR="${pkgdir}" make install
}

package_libogc2-docs-git() {
	pkgdesc+=' (documentation)'
	depends=("${_pkgname}-git")
	provides=("${_pkgname}-docs")
	conflicts=("${_pkgname}-docs")

	cd "${startdir}"
	for platform in gamecube wii; do
		mkdir -p "${pkgdir}${DEVKITPRO}/libogc2/${platform}/share/doc"
		cp -r docs "${pkgdir}${DEVKITPRO}/libogc2/${platform}/share/doc/${_pkgname}"
	done
}