Handle gleam extra_applications

Author: Papipo

lib/mix/lib/mix/dep/loader.ex

@@ -374,13 +374,17 @@ defmodule Mix.Dep.Loader do
     from = Path.join(opts[:dest], "gleam.toml")
     deps = Enum.map(config[:deps], &to_dep(&1, from, _manager = nil, locked?))
 
-    properties = [
-      {:vsn, to_charlist(config[:version])},
-      {:mod, {String.to_atom(config[:mod]), []}}
-    ]
+    properties =
+      [{:vsn, to_charlist(config[:version])}]
+      |> gleam_mod(config)
+      |> gleam_applications(config)
 
     contents = :io_lib.format("~p.~n", [{:application, dep.app, properties}])
 
+    [opts[:build], "ebin"]
+    |> Path.join()
+    |> File.mkdir_p!()
+
     [opts[:build], "ebin", "#{dep.app}.app"]
     |> Path.join()
     |> File.write!(IO.chardata_to_string(contents))
@@ -393,6 +397,24 @@ defmodule Mix.Dep.Loader do
     {dep, Enum.map(children, &to_dep(&1, opts[:dest], _manager = nil, locked?))}
   end
 
+  defp gleam_mod(properties, config) do
+    case config[:mod] do
+      nil -> properties
+      mod -> [{:mod, {String.to_atom(mod), []}} | properties]
+    end
+  end
+
+  defp gleam_applications(properties, config) do
+    case config[:extra_applications] do
+      nil ->
+        properties
+
+      applications ->
+        applications = Enum.map(applications, &String.to_atom/1)
+        [{:applications, applications} | properties]
+    end
+  end
+
   defp mix_children(config, locked?, opts) do
     from = Mix.Project.project_file()
 

lib/mix/lib/mix/gleam.ex

@@ -27,7 +27,7 @@ defmodule Mix.Gleam do
         deps: deps ++ dev_deps
       }
       |> maybe_gleam_version(json)
-      |> maybe_application_start_module(json)
+      |> maybe_erlang_opts(json)
     rescue
       KeyError ->
         Mix.raise("Command \"gleam export package-information\" unexpected format: \n" <> json)
@@ -65,10 +65,16 @@ defmodule Mix.Gleam do
     end
   end
 
-  defp maybe_application_start_module(config, json) do
-    case get_in(json, ["erlang", "application_start_module"]) do
+  defp maybe_erlang_opts(config, json) do
+    config =
+      case get_in(json, ["erlang", "application_start_module"]) do
+        nil -> config
+        mod -> Map.put(config, :mod, mod)
+      end
+
+    case get_in(json, ["erlang", "extra_applications"]) do
       nil -> config
-      mod -> Map.put(config, :mod, mod)
+      extra_applications -> Map.put(config, :extra_applications, extra_applications)
     end
   end
 

lib/mix/test/fixtures/gleam_dep/gleam.toml

@@ -18,3 +18,7 @@ gleam_otp = ">= 0.16.1 and < 1.0.0"
 
 [dev-dependencies]
 gleeunit = ">= 1.0.0 and < 2.0.0"
+
+[erlang]
+extra_applications = ["ssl"]
+application_start_module = "gleam_dep@somemodule"

lib/mix/test/mix/gleam_test.exs

@@ -96,6 +96,12 @@ defmodule Mix.GleamTest do
         assert Enum.any?(load_paths, &String.ends_with?(&1, "gleam_stdlib/ebin"))
         # Dep of a dep
         assert Enum.any?(load_paths, &String.ends_with?(&1, "gleam_erlang/ebin"))
+        {:ok, content} = :file.consult("_build/dev/lib/gleam_dep/ebin/gleam_dep.app")
+
+        assert content == [
+                 {:application, :gleam_dep,
+                  [applications: [:ssl], mod: {:gleam_dep@somemodule, []}, vsn: ~c"1.0.0"]}
+               ]
       end)
     end
   end