Add :generated option to migrations (#580)

Author: greg-rychlewski

lib/ecto/adapters/myxql/connection.ex

@@ -1256,28 +1256,46 @@ if Code.ensure_loaded?(MyXQL) do
     defp options_expr(options),
       do: [?\s, to_string(options)]
 
-    defp column_type(type, _opts) when type in ~w(time utc_datetime naive_datetime)a,
-      do: ecto_to_db(type)
+    defp column_type(type, opts) when type in ~w(time utc_datetime naive_datetime)a do
+      generated = Keyword.get(opts, :generated)
+      [ecto_to_db(type), generated_expr(generated)]
+    end
 
     defp column_type(type, opts)
          when type in ~w(time_usec utc_datetime_usec naive_datetime_usec)a do
       precision = Keyword.get(opts, :precision, 6)
+      generated = Keyword.get(opts, :generated)
       type_name = ecto_to_db(type)
 
-      [type_name, ?(, to_string(precision), ?)]
+      [type_name, ?(, to_string(precision), ?), generated_expr(generated)]
     end
 
     defp column_type(type, opts) do
       size = Keyword.get(opts, :size)
       precision = Keyword.get(opts, :precision)
+      generated = Keyword.get(opts, :generated)
       scale = Keyword.get(opts, :scale)
 
-      cond do
-        size -> [ecto_size_to_db(type), ?(, to_string(size), ?)]
-        precision -> [ecto_to_db(type), ?(, to_string(precision), ?,, to_string(scale || 0), ?)]
-        type == :string -> ["varchar(255)"]
-        true -> ecto_to_db(type)
-      end
+      type =
+        cond do
+          size -> [ecto_size_to_db(type), ?(, to_string(size), ?)]
+          precision -> [ecto_to_db(type), ?(, to_string(precision), ?,, to_string(scale || 0), ?)]
+          type == :string -> ["varchar(255)"]
+          true -> ecto_to_db(type)
+        end
+
+      [type, generated_expr(generated)]
+    end
+
+    defp generated_expr(nil), do: []
+
+    defp generated_expr(expr) when is_binary(expr) do
+      [" AS ", expr]
+    end
+
+    defp generated_expr(other) do
+      raise ArgumentError,
+            "the `:generated` option only accepts strings, received: #{inspect(other)}"
     end
 
     defp reference_expr(type, ref, table, name) do

lib/ecto/adapters/postgres/connection.ex

@@ -1618,56 +1618,82 @@ if Code.ensure_loaded?(Postgrex) do
     defp column_type({:array, type}, opts),
       do: [column_type(type, opts), "[]"]
 
-    defp column_type(type, _opts) when type in ~w(time utc_datetime naive_datetime)a,
-      do: [ecto_to_db(type), "(0)"]
+    defp column_type(type, opts) when type in ~w(time utc_datetime naive_datetime)a do
+      generated = Keyword.get(opts, :generated)
+      [ecto_to_db(type), "(0)", generated_expr(generated)]
+    end
 
     defp column_type(type, opts)
          when type in ~w(time_usec utc_datetime_usec naive_datetime_usec)a do
       precision = Keyword.get(opts, :precision)
+      generated = Keyword.get(opts, :generated)
       type_name = ecto_to_db(type)
 
-      if precision do
-        [type_name, ?(, to_string(precision), ?)]
-      else
-        type_name
-      end
+      type =
+        if precision do
+          [type_name, ?(, to_string(precision), ?)]
+        else
+          type_name
+        end
+
+      [type, generated_expr(generated)]
     end
 
     defp column_type(:identity, opts) do
       start_value = [Keyword.get(opts, :start_value)]
       increment = [Keyword.get(opts, :increment)]
+      generated = Keyword.get(opts, :generated)
       type_name = ecto_to_db(:identity)
 
-      cleanup = fn v -> is_integer(v) and v > 0 end
+      if generated do
+        [type_name, generated_expr(generated)]
+      else
+        cleanup = fn v -> is_integer(v) and v > 0 end
 
-      sequence =
-        start_value
-        |> Enum.filter(cleanup)
-        |> Enum.map(&"START WITH #{&1}")
-        |> Kernel.++(
-          increment
+        sequence =
+          start_value
           |> Enum.filter(cleanup)
-          |> Enum.map(&"INCREMENT BY #{&1}")
-        )
-
-      case sequence do
-        [] -> [type_name, " GENERATED BY DEFAULT AS IDENTITY"]
-        _ -> [type_name, " GENERATED BY DEFAULT AS IDENTITY(", Enum.join(sequence, " "), ") "]
+          |> Enum.map(&"START WITH #{&1}")
+          |> Kernel.++(
+            increment
+            |> Enum.filter(cleanup)
+            |> Enum.map(&"INCREMENT BY #{&1}")
+          )
+
+        case sequence do
+          [] -> [type_name, " GENERATED BY DEFAULT AS IDENTITY"]
+          _ -> [type_name, " GENERATED BY DEFAULT AS IDENTITY(", Enum.join(sequence, " "), ") "]
+        end
       end
     end
 
     defp column_type(type, opts) do
       size = Keyword.get(opts, :size)
       precision = Keyword.get(opts, :precision)
       scale = Keyword.get(opts, :scale)
+      generated = Keyword.get(opts, :generated)
       type_name = ecto_to_db(type)
 
-      cond do
-        size -> [type_name, ?(, to_string(size), ?)]
-        precision -> [type_name, ?(, to_string(precision), ?,, to_string(scale || 0), ?)]
-        type == :string -> [type_name, "(255)"]
-        true -> type_name
-      end
+      type =
+        cond do
+          size -> [type_name, ?(, to_string(size), ?)]
+          precision -> [type_name, ?(, to_string(precision), ?,, to_string(scale || 0), ?)]
+          type == :string -> [type_name, "(255)"]
+          true -> type_name
+        end
+
+      [type, generated_expr(generated)]
+    end
+
+    defp generated_expr(nil), do: []
+
+    defp generated_expr(expr) when is_binary(expr) do
+      [" GENERATED ", expr]
+    end
+
+    defp generated_expr(other) do
+      raise ArgumentError,
+            "the `:generated` option only accepts strings, received: #{inspect(other)}"
     end
 
     defp reference_expr(%Reference{} = ref, table, name) do

lib/ecto/adapters/tds/connection.ex

@@ -1544,7 +1544,19 @@ if Code.ensure_loaded?(Tds) do
       size = Keyword.get(opts, :size)
       precision = Keyword.get(opts, :precision)
       scale = Keyword.get(opts, :scale)
-      ecto_to_db(type, size, precision, scale)
+      generated = Keyword.get(opts, :generated)
+      [ecto_to_db(type, size, precision, scale), generated_expr(generated)]
+    end
+
+    defp generated_expr(nil), do: []
+
+    defp generated_expr(expr) when is_binary(expr) do
+      [" AS ", expr]
+    end
+
+    defp generated_expr(other) do
+      raise ArgumentError,
+            "the `:generated` option only accepts strings, received: #{inspect(other)}"
     end
 
     defp constraint_expr(%Reference{} = ref, table, name) do

lib/ecto/migration.ex

@@ -1092,6 +1092,9 @@ defmodule Ecto.Migration do
         add :summary, :text               # Database type
         add :object,  :map                # Elixir type which is handled by the database
         add :custom, :'"UserDefinedType"' # A case-sensitive, user-defined type name
+        add :identity, :integer, generated: "BY DEFAULT AS IDENTITY" # Postgres generated identity column
+        add :generated_psql, :string, generated: "ALWAYS AS (id::text) STORED" # Postgres calculated column
+        add :generated_other, :string, generated: "CAST(id AS char)" # MySQL and TDS calculated column
       end
 
   ## Options
@@ -1112,6 +1115,9 @@ defmodule Ecto.Migration do
     * `:comment` - adds a comment to the added column.
     * `:after` - positions field after the specified one. Only supported on MySQL,
       it is ignored by other databases.
+    * `:generated` - a string representing the expression for a generated column. See
+      above for a comprehensive set of examples for each of the built-in adapters. If
+      specified alongside `:start_value`/`:increment`, those options will be ignored.
     * `:start_value` - option for `:identity` key, represents initial value in sequence
       generation. Default is defined by the database.
     * `:increment` - option for `:identity` key, represents increment value for

test/ecto/adapters/myxql_test.exs

@@ -1739,6 +1739,22 @@ defmodule Ecto.Adapters.MyXQLTest do
            ]
   end
 
+  test "create table with generated column" do
+    create =
+      {:create, table(:posts),
+       [
+         {:add, :id, :integer, [primary_key: true]},
+         {:add, :id_float, :float, [generated: ~s|(CAST(id AS double))|]}
+       ]}
+
+    assert execute_ddl(create) == [
+             """
+             CREATE TABLE `posts` (`id` integer, `id_float` double AS (CAST(id AS double)), PRIMARY KEY (`id`)) ENGINE = INNODB
+             """
+             |> remove_newlines
+           ]
+  end
+
   test "create table with a map column, and a map default with values" do
     default = %{foo: "bar", baz: "boom"}
     default_text = "'{" <> Enum.map_join(default, ",", fn {k, v} -> ~s{"#{k}":"#{v}"} end) <> "}'"

test/ecto/adapters/postgres_test.exs

@@ -2208,6 +2208,26 @@ defmodule Ecto.Adapters.PostgresTest do
            ]
   end
 
+  test "create table with generated column" do
+    create =
+      {:create, table(:posts),
+       [
+         {:add, :id, :integer,
+          [
+            primary_key: true,
+            generated: "ALWAYS AS IDENTITY (MINVALUE  0 START WITH 0 INCREMENT BY 1)"
+          ]},
+         {:add, :id_str, :string, [generated: ~s|ALWAYS AS (id) STORED|]}
+       ]}
+
+    assert execute_ddl(create) == [
+             """
+             CREATE TABLE "posts" ("id" integer GENERATED ALWAYS AS IDENTITY (MINVALUE  0 START WITH 0 INCREMENT BY 1), "id_str" varchar(255) GENERATED ALWAYS AS (id) STORED, PRIMARY KEY ("id"))
+             """
+             |> remove_newlines
+           ]
+  end
+
   test "create table with binary column and null-byte default" do
     create = {:create, table(:blobs), [{:add, :blob, :binary, [default: <<0>>]}]}
 

test/ecto/adapters/tds_test.exs

@@ -1532,6 +1532,23 @@ defmodule Ecto.Adapters.TdsTest do
            ]
   end
 
+  test "create table with generated column" do
+    create =
+      {:create, table(:posts),
+       [
+         {:add, :id, :integer, [primary_key: true]},
+         {:add, :id_float, :float, [generated: ~s|(CAST(id AS float))|]}
+       ]}
+
+    assert execute_ddl(create) == [
+             """
+             CREATE TABLE [posts] ([id] integer, [id_float] float AS (CAST(id AS float)), CONSTRAINT [posts_pkey] PRIMARY KEY CLUSTERED ([id]));
+             """
+             |> remove_newlines
+             |> Kernel.<>(" ")
+           ]
+  end
+
   test "create table with binary column and UTF-8 default" do
     create = {:create, table(:blobs), [{:add, :blob, :binary, [default: "foo"]}]}