A5200: implement PLOT in graphic modes.

Modes 7 to 11 and 15 are supported.

Author: dmsc

src/interp/a5200/drawto.asm

@@ -27,13 +27,130 @@
 ; Line drawing
 ; ------------
 
+        .importzp       DINDEX, COLOR, IOERROR, COLCRS, ROWCRS, tmp4
+        .importzp       SAVMSC, next_instruction, tmp1
+        .import         gr_mask_p, gr_shift_x, gr_mask_s, EXE_PUT
+
+        .zeropage
+mask:   .res 1
+color_s:.res 1
+
+
 ; TODO: implement line drawing for all graphic modes
+        .segment        "RUNTIME"
+
+.proc   EXE_PLOT        ; Plot a point into current position
+        ; Compatibility: for text modes, this is the same as "PUT":
+        bit     DINDEX
+        bpl     do_plot
+        lda     COLOR
+        jmp     EXE_PUT
+do_plot:
+        jsr     get_addr
+        lda     mask
+        eor     #$FF
+        and     (tmp4), y
+        ora     color_s
+        sta     (tmp4), y
+        jmp     next_instruction
+.endproc
 
 .proc   EXE_DRAWTO      ; Draw line from last position to current
+        jmp     next_instruction
+.endproc
+
+
+.proc   get_addr
+        lda     ROWCRS
+
+        ; Multiply A by 4, overflowing to X
+        ldx     #0
+        asl
+        bcc     L1
+        ldx     #2
+L1:     asl
+        bcc     L2
+        inx
+        clc
+
+        ; Add to original, multiply by 5
+L2:     adc     ROWCRS
+        bcc     :+
+        inx
+:
+        ; And shift 3 times, multiply by 40:
+        stx     tmp4+1
+        asl
+        rol     tmp4+1
+        asl
+        rol     tmp4+1
+        asl
+        rol     tmp4+1
+
+        ; Add to screen address
+        adc     SAVMSC
+        sta     tmp4
+        lda     tmp4+1
+        adc     SAVMSC+1
+        sta     tmp4+1
+        cmp     #$40    ; Compare with top of ram
+        bcs     ret_error
+
+        ; Get mask and shift amounts
+        ldx     DINDEX
+        lda     gr_mask_p, x
+        sta     mask
+
+        ldy     gr_shift_x, x
+
+        ; First shift is 16 bits
+        lda     COLCRS+1
+        lsr
+        lda     COLCRS
+        sta     tmp1
+        lda     #192
+        ; Next shifts are 8 bits
+shift:  ror     tmp1    ; Shift column position
+        ror             ; Shift bit position
+        dey
+        bne     shift
+        ; Here A = bit position * 32, shift 4 more times:
+        rol
+        rol
+        rol
+        rol
+        and     #7
+        eor     #7
+        tax
+
+        ; Generate bit pattern and mask
+        lda     COLOR
+        and     mask
+
+        dex
+        bmi     ok_mask
+rol_mask:
+        asl
+        asl     mask
+        dex
+        bpl     rol_mask
+ok_mask:
+        sta     color_s
+
+        ldy     tmp1
         rts
 .endproc
 
+        ; Return from calling code with error
+ret_error:
+        pla
+        pla
+        lda     #18
+        sta     IOERROR
+        jmp     next_instruction
+
         .include "deftok.inc"
         deftoken "DRAWTO"
+        deftoken "PLOT"
 
 ; vi:syntax=asm_ca65

src/interp/a5200/graphics.asm

@@ -27,7 +27,7 @@
 ; Atari 5200 GRAPHICS statement
 ; -----------------------------
 
-        .export         set_grmode
+        .export         set_grmode, gr_mask_p, gr_shift_x
         .importzp       tmp1, tmp2, next_instruction
         .importzp       DINDEX, COLCRS, ROWCRS, SAVMSC, COLOR
         .import         mem_set_0, MEMTOP, GPRIOR
@@ -209,6 +209,10 @@ dl_adr_l:       .lobytes $3098, $2126, $2126, $2126, $3E00, $3EF0, $3C20, $3E00
 dl_adr_h:       .hibytes $3098, $2126, $2126, $2126, $3E00, $3EF0, $3C20, $3E00
 rows:           .byte       96,   192,   192,   192,    24,    12,    24,    12
 
+                ;       2bpp    1bpp    4bpp    2bpp
+gr_mask_p:      .byte   3,      1,     15,      3
+gr_shift_x:     .byte   2,      3,      1,      2
+
         .include "deftok.inc"
         deftoken "GRAPHICS"
 

src/syntax/gr-a5200.syn

@@ -19,7 +19,7 @@
 # Graphic support statements for the Atari 5200
 
 TOKENS {
- TOK_GRAPHICS, TOK_DRAWTO
+ TOK_GRAPHICS, TOK_DRAWTO, TOK_PLOT
 }
 
 SYMBOLS {
@@ -30,7 +30,7 @@ SYMBOLS {
 STATEMENT:
         "Graphics" emit { TOK_0, TOK_PMGRAPHICS } EXPR emit TOK_GRAPHICS
         "Color"  EXPR emit { TOK_BYTE_POKE, COLOR }
-        "PLot" POSITION emit { TOK_BYTE_PEEK, COLOR, TOK_PUT }
+        "PLot" POSITION emit { TOK_PLOT }
         "DRawto" POSITION emit { TOK_DRAWTO }
         "SEtcolor" EXPR emit { TOK_PUSH_NUM, &COLOR0, TOK_ADD, TOK_SADDR } EXPR_AB emit TOK_POKE