Bintray and Maven plugins

Author: hzalaz

auth0/build.gradle

@@ -36,6 +36,9 @@ artifacts {
     archives javadocJar
 }
 
+apply from: '../maven.gradle'
+apply from: '../bintray.gradle'
+
 def defineVersion() {
     def current = describeGit(false)
     def snapshot = current == null

bintray.gradle

@@ -0,0 +1,33 @@
+def bintrayUser = getProperty('bintray.user')
+def bintrayApiKey = getProperty('bintray.key')
+def bintrayPassphrase = getProperty('bintray.gpg.password')
+
+if (bintrayUser != null && bintrayApiKey != null && bintrayPassphrase != null) {
+    apply plugin: 'com.jfrog.bintray'
+    bintray {
+        user = bintrayUser
+        key = bintrayApiKey
+        configurations = ['archives']
+        dryRun = project.version.endsWith("-SNAPSHOT")
+        publish = false
+        pkg {
+            repo = 'lock-android'
+            name = project.name
+            desc = 'Java client library for the Auth0 platform'
+            websiteUrl = 'https://github.com/auth0/auth0-api-java'
+            vcsUrl = 'scm:git@github.com:auth0/auth0-api-java.git'
+            licenses = ["MIT"]
+            userOrg = 'auth0'
+            publish = false
+            version {
+                gpg {
+                    sign = true
+                    passphrase = bintrayPassphrase
+                }
+                vcsTag = project.version
+                name = project.version
+                released = new Date()
+            }
+        }
+    }
+}

build.gradle

@@ -6,3 +6,14 @@ allprojects {
     }
 }
 
+buildscript {
+    repositories {
+        jcenter()
+    }
+
+    dependencies {
+        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.6'
+    }
+}
+
+

maven.gradle

@@ -0,0 +1,37 @@
+apply plugin: 'maven'
+
+install {
+    repositories.mavenInstaller {
+        pom {
+            project {
+                packaging 'jar'
+                artifactId 'auth0'
+
+                name 'Auth0'
+                description 'Java client library for the Auth0 platform'
+                url 'https://github.com/auth0/auth0-api-java'
+
+                licenses {
+                    license {
+                        name 'The MIT License (MIT)'
+                        url 'https://raw.githubusercontent.com/auth0/auth0-api-java/master/LICENSE'
+                        distribution 'repo'
+                    }
+                }
+                developers {
+                    developer {
+                        id 'hzalaz'
+                        name 'Hernan Zalazar'
+                        email 'hernan@auth0.com'
+                    }
+                }
+                scm {
+                    connection 'scm:git@github.com:auth0/auth0-api-java.git'
+                    developerConnection 'scm:git@github.com:auth0/auth0-api-java.git'
+                    url 'https://github.com/auth0/auth0-api-java'
+
+                }
+            }
+        }
+    }
+}