Use git describe to infer version name

Author: hzalaz

build.gradle

@@ -1,6 +1,5 @@
 allprojects {
     group = 'com.auth0'
-    version = '0.0.1-SNAPSHOT'
 
     repositories {
         jcenter()

lib/build.gradle

@@ -14,3 +14,55 @@ dependencies {
     testCompile 'com.squareup.okhttp:mockwebserver:2.5.0'
     testCompile 'com.jayway.awaitility:awaitility:1.6.4'
 }
+
+def semver = defineVersion()
+version = semver.stringVersion
+
+jar {
+    baseName = "auth0"
+}
+
+logger.lifecycle("Using version ${version} for ${name}")
+
+def defineVersion() {
+    def current = describeGit(false)
+    def snapshot = current == null
+    if (snapshot) {
+        current = describeGit(snapshot, "0.0.1")
+    }
+    return new Semver(snapshot: snapshot, version: current)
+}
+
+def describeGit(boolean snapshot, String defaultValue = null) {
+    def arguments = ['describe', '--tags']
+    arguments.add(snapshot ? '--abbrev=0' : '--exact-match')
+    def stdout = new ByteArrayOutputStream()
+    def string = defaultValue
+    try {
+        def result = project.exec {
+            executable = 'git'
+            args = arguments
+            standardOutput = stdout
+        }
+
+        result.assertNormalExitValue()
+
+        if (stdout.toByteArray().length > 0) {
+            string = stdout.toString().replace("\n", "")
+        }
+    } catch(Exception e) {
+        logger.debug("Failed git describe command", e)
+    } finally {
+        stdout.close()
+    }
+    return string
+}
+
+class Semver {
+    def version
+    def snapshot
+
+    def getStringVersion() {
+        return snapshot ? version + "-SNAPSHOT" : version
+    }
+}