fix: extract params from routes for GET actions (#416)

fixes #349

Author: ascogeno

lib/ash_json_api/request.ex

@@ -1060,13 +1060,53 @@ defmodule AshJsonApi.Request do
     String.to_existing_atom(string)
   end
 
+  defp parse_query_params(
+         %{route: %{type: :route, method: method} = route, action: action} = request
+       )
+       when method in [:get, "GET"] do
+    path_param_names =
+      route.route
+      |> Path.split()
+      |> Enum.filter(&String.starts_with?(&1, ":"))
+      |> Enum.map(&String.trim_leading(&1, ":"))
+
+    action_arg_entries =
+      action.arguments
+      |> Enum.filter(& &1.public?)
+      |> Enum.reject(fn arg -> to_string(arg.name) in path_param_names end)
+      |> Enum.map(fn arg -> {arg.name, to_string(arg.name)} end)
+
+    route_param_entries =
+      route.query_params
+      |> List.wrap()
+      |> Enum.map(fn qp -> {qp, to_string(qp)} end)
+
+    effective_entries =
+      Enum.uniq_by(route_param_entries ++ action_arg_entries, fn {atom, _} -> atom end)
+
+    Enum.reduce(effective_entries, request, fn {atom_key, string_key}, request ->
+      case Map.fetch(request.query_params, string_key) do
+        {:ok, value} ->
+          args = request.arguments || %{}
+          %{request | arguments: Map.put(args, atom_key, value)}
+
+        :error ->
+          request
+      end
+    end)
+  end
+
   defp parse_query_params(%{route: route} = request) do
     route.query_params
     |> List.wrap()
     |> Enum.reduce(request, fn query_param, request ->
       case Map.fetch(request.query_params, to_string(query_param)) do
-        {:ok, value} -> %{request | arguments: Map.put(request.arguments, query_param, value)}
-        :error -> request
+        {:ok, value} ->
+          args = request.arguments || %{}
+          %{request | arguments: Map.put(args, query_param, value)}
+
+        :error ->
+          request
       end
     end)
   end

test/acceptance/generic_action_index_test.exs

@@ -65,6 +65,67 @@ defmodule Test.Acceptance.GenericActionIndexTest do
     end
   end
 
+  defmodule SearchResultImplicitQueryParams do
+    use Ash.Resource,
+      domain: Test.Acceptance.GenericActionIndexTest.Domain,
+      extensions: [AshJsonApi.Resource]
+
+    resource do
+      require_primary_key?(false)
+    end
+
+    json_api do
+      type("search_result_implicit")
+
+      routes do
+        base("/search_implicit")
+        # Intentionally no query_params: [...]
+        route(:get, "/", :search)
+      end
+    end
+
+    actions do
+      action :search, {:array, :struct} do
+        constraints(items: [instance_of: __MODULE__])
+        argument(:query, :string, allow_nil?: false)
+        argument(:category, :string, allow_nil?: true)
+
+        run(fn input, _ ->
+          query = input.arguments.query
+          category = Map.get(input.arguments, :category)
+
+          results =
+            case category do
+              nil ->
+                [
+                  %__MODULE__{title: "Result 1 for #{query}", content: "Content 1"},
+                  %__MODULE__{title: "Result 2 for #{query}", content: "Content 2"}
+                ]
+
+              category ->
+                [
+                  %__MODULE__{
+                    title: "#{category} Result 1 for #{query}",
+                    content: "Category content 1"
+                  },
+                  %__MODULE__{
+                    title: "#{category} Result 2 for #{query}",
+                    content: "Category content 2"
+                  }
+                ]
+            end
+
+          {:ok, results}
+        end)
+      end
+    end
+
+    attributes do
+      attribute(:title, :string, public?: true)
+      attribute(:content, :string, public?: true)
+    end
+  end
+
   defmodule Domain do
     use Ash.Domain,
       otp_app: :ash_json_api,
@@ -78,6 +139,7 @@ defmodule Test.Acceptance.GenericActionIndexTest do
 
     resources do
       resource(SearchResult)
+      resource(SearchResultImplicitQueryParams)
     end
   end
 
@@ -151,6 +213,23 @@ defmodule Test.Acceptance.GenericActionIndexTest do
            "Expected source pointer '#{source_pointer}' to be /query"
   end
 
+  test "generic action index route accepts optional argument without query_params configured" do
+    response =
+      Domain
+      |> get("/search_implicit?query=elixir&category=tutorial", status: 200)
+
+    assert response.resp_body == [
+             %{
+               "title" => "tutorial Result 1 for elixir",
+               "content" => "Category content 1"
+             },
+             %{
+               "title" => "tutorial Result 2 for elixir",
+               "content" => "Category content 2"
+             }
+           ]
+  end
+
   test "generic GET actions include arguments as query parameters in JSON schema" do
     schema = AshJsonApi.JsonSchema.generate([Domain])