build: Fix flake

Author: a3li

flake.lock

@@ -3,11 +3,21 @@
     nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
     flake-utils.url = "github:numtide/flake-utils";
     flake-parts.url = "github:hercules-ci/flake-parts";
-    poetry2nix = {
-      url = "github:nix-community/poetry2nix";
+    pyproject-nix = {
+      url = "github:nix-community/pyproject.nix";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+    uv2nix = {
+      url = "github:adisbladis/uv2nix";
+      inputs.pyproject-nix.follows = "pyproject-nix";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+    pyproject-build-systems = {
+      url = "github:pyproject-nix/build-system-pkgs";
       inputs = {
+        pyproject-nix.follows = "pyproject-nix";
+        uv2nix.follows = "uv2nix";
         nixpkgs.follows = "nixpkgs";
-        flake-utils.follows = "flake-utils";
       };
     };
   };
@@ -23,31 +33,45 @@
         ];
 
         perSystem =
-          { pkgs, self', ... }:
+          {
+            pkgs,
+            lib,
+            self',
+            ...
+          }:
           let
-            poetry2nix = import inputs.poetry2nix { inherit pkgs; };
-            overrides = poetry2nix.overrides.withDefaults (
-              final: prev: {
-                pygeodesy = prev.pygeodesy.overridePythonAttrs (old: {
-                  nativeBuildInputs = (old.nativeBuildInputs or [ ]) ++ [ final.setuptools ];
-                });
-              }
-            );
-            devEnv = poetry2nix.mkPoetryEnv {
-              inherit overrides;
-              projectDir = ./.;
-              editablePackageSources = {
-                mapbuilder = ./.;
-              };
+            workspace = inputs.uv2nix.lib.workspace.loadWorkspace { workspaceRoot = ./.; };
+            overlay = workspace.mkPyprojectOverlay {
+              sourcePreference = "wheel";
             };
+
+            python = pkgs.python314;
+
+            pythonSet =
+              (pkgs.callPackage inputs.pyproject-nix.build.packages {
+                inherit python;
+              }).overrideScope
+                (
+                  lib.composeManyExtensions [
+                    inputs.pyproject-build-systems.overlays.default
+                    overlay
+                    (final: prev: {
+                      fiona = prev.fiona.overrideAttrs (old: {
+                        nativeBuildInputs = old.nativeBuildInputs ++ [
+                          pkgs.gdal
+                          (final.resolveBuildSystem {
+                            setuptools = [ ];
+                            cython = [ ];
+                          })
+                        ];
+                      });
+                    })
+                  ]
+                );
           in
           {
             packages = {
-              default = poetry2nix.mkPoetryApplication {
-                inherit overrides;
-                projectDir = ./.;
-                checkGroups = [ ];
-              };
+              mapbuilder = (pythonSet.mkVirtualEnv "mapbuilder-env" workspace.deps.default);
 
               docker = pkgs.dockerTools.buildLayeredImage {
                 name = "ghcr.io/vatger-nav/mapbuilder";
@@ -56,7 +80,7 @@
                 contents = [
                   pkgs.cacert
                   pkgs.tzdata
-                  self'.packages.default
+                  self'.packages.mapbuilder
                 ];
 
                 config = {
@@ -65,23 +89,62 @@
                     "PYTHONDONTWRITEBYTECODE=1"
                     "PYTHONUNBUFFERED=1"
                   ];
-                  WorkingDir = "/";
+                  WorkingDir = "/bin";
                   Entrypoint = [ "mapbuilder" ];
                 };
               };
             };
 
-            devShells.default = devEnv.env.overrideAttrs (attrs: {
-              nativeBuildInputs = attrs.nativeBuildInputs ++ [
-                pkgs.poetry
-                pkgs.pyright
-              ];
-              shellHook = ''
-                export PYTHONPATH=${devEnv}/${devEnv.sitePackages}
-              '';
-            });
+            devShells =
+              let
+                editableOverlay = workspace.mkEditablePyprojectOverlay {
+                  root = "$REPO_ROOT";
+                };
+                editablePythonSet = pythonSet.overrideScope (
+                  lib.composeManyExtensions [
+                    editableOverlay
+                    (final: prev: {
+                      mapbuilder = prev.mapbuilder.overrideAttrs (old: {
+                        # Hatchling (our build system) has a dependency on the `editables` package when building editables.
+                        #
+                        # In normal Python flows this dependency is dynamically handled, and doesn't need to be explicitly declared.
+                        # This behaviour is documented in PEP-660.
+                        #
+                        # With Nix the dependency needs to be explicitly declared.
+                        nativeBuildInputs =
+                          old.nativeBuildInputs
+                          ++ final.resolveBuildSystem {
+                            editables = [ ];
+                          };
+                      });
+                    })
+                  ]
+                );
+                virtualenv = editablePythonSet.mkVirtualEnv "mapbuilder-dev-env" workspace.deps.all;
+                commonPackages = [
+                  virtualenv
+                  pkgs.uv
+                ];
+              in
+              {
+                default = pkgs.mkShell {
+                  packages = commonPackages;
+                  env = {
+                    # Don't create venv using uv
+                    UV_NO_SYNC = "1";
+
+                    # Force uv to use Python interpreter from venv
+                    UV_PYTHON = "${virtualenv}/bin/python";
+
+                    # Prevent uv from downloading managed Python's
+                    UV_PYTHON_DOWNLOADS = "never";
+
+                    PYTHONPATH = ".:${virtualenv}/${python.sitePackages}";
+                  };
+                };
+              };
 
-            formatter = pkgs.nixfmt-rfc-style;
+            formatter = pkgs.nixfmt;
           };
       }
     );

flake.nix

@@ -34,9 +34,6 @@ dev = [
     "lxml-stubs>=0.5,<0.6",
 ]
 
-[tool.uv]
-default-groups = "all"
-
 [tool.uv.build-backend]
 module-root = ""