CodexUI/CMakeLists.txt at master · SNodeC/CodexUI · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
# SPDX-License-Identifier: LGPL-3.0-or-later OR MIT

cmake_minimum_required(VERSION 3.20)

project(CodexUI VERSION 1.0.0 LANGUAGES CXX)

include(GNUInstallDirs)
include(CTest)

set(CMAKE_AUTOMOC ON)

find_package(AISuite CONFIG REQUIRED)
find_package(
    snodec 2.0 CONFIG REQUIRED
    COMPONENTS net-un-stream-legacy net-in-stream-legacy net-in6-stream-legacy
)
find_package(
    snodec 2.0 CONFIG QUIET
    COMPONENTS net-in-stream-tls net-in6-stream-tls
)
find_package(
    snodec 2.0 CONFIG QUIET
    COMPONENTS net-rc-stream-legacy net-rc-stream-tls
)
find_package(Qt6 REQUIRED COMPONENTS Widgets)
find_package(PkgConfig REQUIRED)
pkg_check_modules(LIBGIT2 REQUIRED IMPORTED_TARGET libgit2)
find_package(Threads REQUIRED)

set(
    CODEXUI_CODEX_COMMON_SOURCES
    src/codex/AttachmentDraft.h
    src/codex/ClientRuntime.cpp
    src/codex/ClientRuntime.h
    src/codex/Configuration.cpp
    src/codex/Configuration.h
    src/codex/ConnectionDialog.cpp
    src/codex/ConnectionDialog.h
    src/codex/DiffViewer.cpp
    src/codex/DiffViewer.h
    src/codex/FrontendSession.cpp
    src/codex/FrontendSession.h
    src/codex/GitDiffProvider.cpp
    src/codex/GitDiffProvider.h
    src/codex/FileSelectionDialog.cpp
    src/codex/FileSelectionDialog.h
    src/codex/MainWindow.cpp
    src/codex/MainWindow.h
    src/codex/NewThreadDialog.cpp
    src/codex/NewThreadDialog.h
    src/codex/PendingRequestPolicy.cpp
    src/codex/PendingRequestPolicy.h
    src/codex/PresentationModel.cpp
    src/codex/PresentationModel.h
    src/codex/PresentationClient.h
    src/codex/PresentationStatus.h
    src/codex/PresentationProtocol.cpp
    src/codex/PresentationProtocol.h
    src/codex/ProtocolNormalizer.cpp
    src/codex/ProtocolNormalizer.h
    src/codex/UiSession.cpp
    src/codex/UiSession.h
    src/codex/ipc/QtSocketPairEndpoint.cpp
    src/codex/ipc/QtSocketPairEndpoint.h
    src/codex/ipc/SNodeSocketPairEndpoint.cpp
    src/codex/ipc/SNodeSocketPairEndpoint.h
    src/codex/ipc/SocketPair.cpp
    src/codex/ipc/SocketPair.h
    src/codex/main.cpp
    src/codex/ui/ExpandingPromptEditor.cpp
    src/codex/ui/ExpandingPromptEditor.h
    src/codex/ui/BrandMark.cpp
    src/codex/ui/BrandMark.h
    src/codex/ui/UiStyle.cpp
    src/codex/ui/UiStyle.h
    src/codex/ui/UiViewProjection.cpp
    src/codex/ui/UiViewProjection.h
    src/codex/ui/UiViewState.h
)

set(
    CODEXUI_SHELL_SOURCES
    src/codex/ShellWidget.cpp
    src/codex/ShellWidget.h
    src/codex/middle/ComposerPane.cpp
    src/codex/middle/ComposerPane.h
    src/codex/middle/ConversationCards.cpp
    src/codex/middle/ConversationCards.h
    src/codex/middle/ConversationProjection.cpp
    src/codex/middle/ConversationProjection.h
    src/codex/middle/ConversationView.cpp
    src/codex/middle/ConversationView.h
    src/codex/middle/InspectorPane.cpp
    src/codex/middle/InspectorPane.h
    src/codex/middle/MiddleRegionWidget.cpp
    src/codex/middle/MiddleRegionWidget.h
    src/codex/middle/MiddleTypes.cpp
    src/codex/middle/MiddleTypes.h
    src/codex/middle/PromptCoordinator.cpp
    src/codex/middle/PromptCoordinator.h
    src/codex/middle/ThreadPane.cpp
    src/codex/middle/ThreadPane.h
)

qt_add_executable(
    codex-ui
    ${CODEXUI_CODEX_COMMON_SOURCES}
    ${CODEXUI_SHELL_SOURCES}
    src/codex/PendingRequestDialog.cpp
    src/codex/PendingRequestDialog.h
    src/codex/TurnSettingsWidget.cpp
    src/codex/TurnSettingsWidget.h
)
function(configure_codexui_target target)
    target_compile_features(${target} PRIVATE cxx_std_20)
    target_include_directories(${target} PRIVATE src)
    target_link_libraries(
        ${target}
        PRIVATE
            AISuite::OpenAICodex
            PkgConfig::LIBGIT2
            Qt6::Widgets
            Threads::Threads
            snodec::net-un-stream-legacy
            snodec::net-in-stream-legacy
            snodec::net-in6-stream-legacy
    )
endfunction()

configure_codexui_target(codex-ui)

option(CODEXUI_INSTALL_WEB "Require and install the CodexWebUI production artifact" ON)
if(CODEXUI_INSTALL_WEB)
    add_subdirectory(web)
else()
    message(STATUS "CodexWebUI packaging disabled by CODEXUI_INSTALL_WEB=OFF")
endif()

if(TARGET snodec::net-in-stream-tls AND TARGET snodec::net-in6-stream-tls)
    target_compile_definitions(codex-ui PRIVATE CODEXUI_CODEX_FRONTEND_TLS=1)
    target_link_libraries(
        codex-ui PRIVATE snodec::net-in-stream-tls snodec::net-in6-stream-tls
    )
endif()

if(TARGET snodec::net-rc-stream-legacy AND TARGET snodec::net-rc-stream-tls)
    target_compile_definitions(codex-ui PRIVATE CODEXUI_CODEX_FRONTEND_RFCOMM=1)
    target_link_libraries(
        codex-ui PRIVATE snodec::net-rc-stream-legacy snodec::net-rc-stream-tls
    )
endif()

if(TARGET snodec::http-client AND TARGET snodec::websocket-client)
    target_compile_definitions(codex-ui PRIVATE CODEXUI_CODEX_FRONTEND_WEBSOCKET=1)
    target_link_libraries(codex-ui PRIVATE snodec::http-client snodec::websocket-client)
endif()

if(BUILD_TESTING)
    add_executable(
        codexui-socketpair-contract-test
        tests/codex/SocketPairContractTest.cpp
        src/codex/ipc/QtSocketPairEndpoint.cpp
        src/codex/ipc/QtSocketPairEndpoint.h
        src/codex/ipc/SNodeSocketPairEndpoint.cpp
        src/codex/ipc/SNodeSocketPairEndpoint.h
        src/codex/ipc/SocketPair.cpp
        src/codex/ipc/SocketPair.h
    )
    target_compile_features(
        codexui-socketpair-contract-test PRIVATE cxx_std_20
    )
    target_include_directories(
        codexui-socketpair-contract-test PRIVATE src
    )
    target_link_libraries(
        codexui-socketpair-contract-test
        PRIVATE Qt6::Core Threads::Threads snodec::net-un-stream-legacy
    )
    add_test(
        NAME codexui-socketpair-contract
        COMMAND codexui-socketpair-contract-test
    )
    set_tests_properties(
        codexui-socketpair-contract PROPERTIES TIMEOUT 10
    )

    add_executable(
        codexui-presentation-pipeline-test
        tests/codex/PresentationPipelineTest.cpp
        src/codex/PresentationModel.cpp
        src/codex/PresentationModel.h
        src/codex/PresentationProtocol.cpp
        src/codex/PresentationProtocol.h
        src/codex/ProtocolNormalizer.cpp
        src/codex/ProtocolNormalizer.h
    )
    target_compile_features(
        codexui-presentation-pipeline-test PRIVATE cxx_std_20
    )
    target_include_directories(
        codexui-presentation-pipeline-test PRIVATE src
    )
    target_link_libraries(
        codexui-presentation-pipeline-test
        PRIVATE AISuite::OpenAICodex
    )
    add_test(
        NAME codexui-presentation-pipeline
        COMMAND codexui-presentation-pipeline-test
    )
    set_tests_properties(
        codexui-presentation-pipeline PROPERTIES TIMEOUT 10
    )

    add_executable(
        codexui-pending-request-policy-test
        tests/codex/PendingRequestPolicyTest.cpp
        src/codex/PendingRequestPolicy.cpp
        src/codex/PendingRequestPolicy.h
    )
    target_compile_features(
        codexui-pending-request-policy-test PRIVATE cxx_std_20
    )
    target_include_directories(
        codexui-pending-request-policy-test PRIVATE src
    )
    add_test(
        NAME codexui-pending-request-policy
        COMMAND codexui-pending-request-policy-test
    )
    set_tests_properties(
        codexui-pending-request-policy PROPERTIES TIMEOUT 10
    )

    add_executable(
        codexui-ui-session-test
        tests/codex/UiSessionTest.cpp
        src/codex/UiSession.cpp
        src/codex/UiSession.h
        src/codex/PendingRequestPolicy.cpp
        src/codex/PendingRequestPolicy.h
        src/codex/PresentationClient.h
        src/codex/PresentationModel.cpp
        src/codex/PresentationModel.h
        src/codex/PresentationProtocol.cpp
        src/codex/PresentationProtocol.h
        src/codex/PresentationStatus.h
        src/codex/AttachmentDraft.h
        src/codex/ui/UiViewProjection.cpp
        src/codex/ui/UiViewProjection.h
        src/codex/ui/UiViewState.h
        src/codex/middle/ConversationProjection.cpp
        src/codex/middle/ConversationProjection.h
        src/codex/middle/MiddleTypes.cpp
        src/codex/middle/MiddleTypes.h
        src/codex/middle/PromptCoordinator.cpp
        src/codex/middle/PromptCoordinator.h
    )
    target_compile_features(codexui-ui-session-test PRIVATE cxx_std_20)
    target_include_directories(codexui-ui-session-test PRIVATE src)
    add_test(NAME codexui-ui-session COMMAND codexui-ui-session-test)
    set_tests_properties(codexui-ui-session PROPERTIES TIMEOUT 10)

    add_executable(
        codexui-conversation-projection-test
        tests/codex/ConversationProjectionTest.cpp
        src/codex/middle/ConversationProjection.cpp
        src/codex/middle/ConversationProjection.h
        src/codex/middle/MiddleTypes.cpp
        src/codex/middle/MiddleTypes.h
        src/codex/middle/PromptCoordinator.cpp
        src/codex/middle/PromptCoordinator.h
        src/codex/AttachmentDraft.h
    )
    target_compile_features(
        codexui-conversation-projection-test PRIVATE cxx_std_20
    )
    target_include_directories(codexui-conversation-projection-test PRIVATE src)
    add_test(
        NAME codexui-conversation-projection
        COMMAND codexui-conversation-projection-test
    )
    set_tests_properties(
        codexui-conversation-projection PROPERTIES TIMEOUT 10
    )

    qt_add_executable(
        codexui-conversation-cards-test
        tests/codex/ConversationCardsTest.cpp
        src/codex/middle/ConversationCards.cpp
        src/codex/middle/ConversationCards.h
        src/codex/middle/ConversationView.cpp
        src/codex/middle/ConversationView.h
        src/codex/middle/MiddleTypes.cpp
        src/codex/middle/MiddleTypes.h
        src/codex/ui/UiStyle.cpp
        src/codex/ui/UiStyle.h
    )
    target_compile_features(
        codexui-conversation-cards-test PRIVATE cxx_std_20
    )
    target_include_directories(codexui-conversation-cards-test PRIVATE src)
    target_link_libraries(
        codexui-conversation-cards-test PRIVATE Qt6::Widgets
    )
    add_test(
        NAME codexui-conversation-cards
        COMMAND codexui-conversation-cards-test
    )
    set_tests_properties(
        codexui-conversation-cards
        PROPERTIES TIMEOUT 15 ENVIRONMENT "QT_QPA_PLATFORM=offscreen"
    )

    qt_add_executable(
        codexui-application-layout-test
        tests/codex/ApplicationLayoutTest.cpp
        src/codex/DiffViewer.cpp
        src/codex/DiffViewer.h
        src/codex/GitDiffProvider.cpp
        src/codex/GitDiffProvider.h
        src/codex/FileSelectionDialog.cpp
        src/codex/FileSelectionDialog.h
        src/codex/PresentationModel.cpp
        src/codex/PresentationModel.h
        src/codex/PresentationProtocol.cpp
        src/codex/PresentationProtocol.h
        src/codex/TurnSettingsWidget.cpp
        src/codex/TurnSettingsWidget.h
        src/codex/ui/ExpandingPromptEditor.cpp
        src/codex/ui/ExpandingPromptEditor.h
        src/codex/ui/UiStyle.cpp
        src/codex/ui/UiStyle.h
        src/codex/ui/UiViewProjection.cpp
        src/codex/ui/UiViewProjection.h
        src/codex/ui/UiViewState.h
        src/codex/middle/ComposerPane.cpp
        src/codex/middle/ComposerPane.h
        src/codex/middle/ConversationCards.cpp
        src/codex/middle/ConversationCards.h
        src/codex/middle/ConversationView.cpp
        src/codex/middle/ConversationView.h
        src/codex/middle/InspectorPane.cpp
        src/codex/middle/InspectorPane.h
        src/codex/middle/MiddleRegionWidget.cpp
        src/codex/middle/MiddleRegionWidget.h
        src/codex/middle/MiddleTypes.cpp
        src/codex/middle/MiddleTypes.h
        src/codex/middle/ThreadPane.cpp
        src/codex/middle/ThreadPane.h
    )
    target_compile_features(
        codexui-application-layout-test PRIVATE cxx_std_20
    )
    target_include_directories(codexui-application-layout-test PRIVATE src)
    target_link_libraries(
        codexui-application-layout-test
        PRIVATE AISuite::OpenAICodex PkgConfig::LIBGIT2 Qt6::Widgets
    )
    add_test(
        NAME codexui-application-layout
        COMMAND codexui-application-layout-test
    )
    set_tests_properties(
        codexui-application-layout
        PROPERTIES TIMEOUT 15 ENVIRONMENT "QT_QPA_PLATFORM=offscreen"
    )

    qt_add_executable(
        codexui-git-changes-live-test
        tests/codex/GitChangesLiveTest.cpp
        src/codex/DiffViewer.cpp
        src/codex/DiffViewer.h
        src/codex/GitDiffProvider.cpp
        src/codex/GitDiffProvider.h
        src/codex/ui/UiStyle.cpp
        src/codex/ui/UiStyle.h
    )
    target_compile_features(codexui-git-changes-live-test PRIVATE cxx_std_20)
    target_include_directories(codexui-git-changes-live-test PRIVATE src)
    target_link_libraries(
        codexui-git-changes-live-test PRIVATE PkgConfig::LIBGIT2 Qt6::Widgets
    )
    add_test(
        NAME codexui-git-changes-live
        COMMAND codexui-git-changes-live-test
    )
    set_tests_properties(
        codexui-git-changes-live
        PROPERTIES TIMEOUT 30 ENVIRONMENT "QT_QPA_PLATFORM=offscreen"
    )

    set(CODEXUI_SHELL_TEST_SOURCES ${CODEXUI_CODEX_COMMON_SOURCES})
    list(
        REMOVE_ITEM CODEXUI_SHELL_TEST_SOURCES
        src/codex/main.cpp
        src/codex/MainWindow.cpp
        src/codex/MainWindow.h
    )
    qt_add_executable(
        codexui-shell-integration-test
        tests/codex/ShellIntegrationTest.cpp
        ${CODEXUI_SHELL_TEST_SOURCES}
        ${CODEXUI_SHELL_SOURCES}
        src/codex/PendingRequestDialog.cpp
        src/codex/PendingRequestDialog.h
        src/codex/TurnSettingsWidget.cpp
        src/codex/TurnSettingsWidget.h
    )
    configure_codexui_target(codexui-shell-integration-test)
    add_test(
        NAME codexui-shell-integration
        COMMAND codexui-shell-integration-test
    )
    set_tests_properties(
        codexui-shell-integration
        PROPERTIES TIMEOUT 20 ENVIRONMENT "QT_QPA_PLATFORM=offscreen"
    )

endif()

install(
    TARGETS codex-ui
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
    BUNDLE DESTINATION .
)
install(
    FILES resources/icons/codex-ui.svg
    DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/icons/hicolor/scalable/apps
)
install(
    FILES resources/applications/codex-ui.desktop
    DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/applications
)