java-core-lib/test.gradle at master · BitWeb/java-core-lib · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
apply plugin: 'jacoco'

test {
    useJUnitPlatform()
}

tasks.register('unitTest', Test) {
    group = "verification"

    testClassesDirs = sourceSets.test.output.classesDirs
    classpath = sourceSets.test.runtimeClasspath

    useJUnitPlatform {
        excludeTags "integration"
    }
}

tasks.register('integrationTest', Test) {
    group = "verification"

    testClassesDirs = sourceSets.test.output.classesDirs
    classpath = sourceSets.test.runtimeClasspath

    useJUnitPlatform {
        includeTags 'integration'
    }
}

tasks.register('jacocoUnitTestReport', JacocoReport) {
    sourceSets sourceSets.main
    executionData unitTest

    reports {
        xml.required = true
    }
}

tasks.register('jacocoIntegrationTestReport', JacocoReport) {
    sourceSets sourceSets.main
    executionData integrationTest

    reports {
        xml.required = true
    }
}

tasks.register('testAndReport') {
    tasks.getByName('integrationTest').mustRunAfter('unitTest')
    dependsOn('unitTest', 'integrationTest', 'jacocoUnitTestReport', 'jacocoIntegrationTestReport')
}